.config/fish/config.fish



if status is-interactive
    if type -qf zoxide
        zoxide init fish | source
    end
    if type -qf devenv
        devenv hook fish | source
    end

    if type -q fundle
        fundle plugin 'PatrickF1/fzf.fish'

        fundle init
    end

    if type -q fzf_configure_bindings
        fzf_configure_bindings --directory= --git_log= --git_status= --processes= --variables=
        set fzf_diff_highlighter delta --paging=never --width=20
    end

    function mkcd --description "Make a directory and cd into it"
        mkdir -p $argv[1]
        cd $argv[1]
    end

    function rm --wraps rm
        if string match -qr -- '^-[rf]' $argv || not type -qf trash
            command rm $argv
        else
            echo "No. Use trash or shred instead."
        end
    end

    function dot --wraps git --description "Performs git actions on the dotfiles repo"
        git -C ~/Projects/dotfiles $argv
    end

    function upgrade
        sudo pacman -Syuu
        flatpak update
        fundle update
        dot pull
    end

    alias ls="eza"
    alias ll="ls -l"
    alias la="ls -A"
    alias lla="ls -lA"
    alias lal="ls -Al"
    alias tree="eza -T"

    alias hx="helix"
    alias bios="systemctl reboot --firmware-setup"
    alias stow="stow -t ~"
end