@group(0) @binding(0)
var<uniform> camera: mat4x4<f32>;

struct VertexInput {
	@location(0) position: vec2<f32>
}

struct InstanceInput {
	@location(1) position: vec2<f32>,
	@location(2) size: vec2<f32>,
	@location(3) texture_coordinates: vec2<f32>,
	@location(4) texture_size: vec2<f32>,
}

struct VertexOutput {
	@builtin(position) clip_position: vec4<f32>,
	@location(0) texture_coordinates: vec2<f32>,
}

@vertex
fn vs_main(model: VertexInput, instance: InstanceInput) -> VertexOutput {
	var out: VertexOutput;

	// scale the sprite
	let scaled = model.position * instance.size;

	// move the sprite
	let position2d = scaled + instance.position;

	// camera stuff
	let position4d = vec4<f32>(position2d, 0.0, 1.0);
	let position = camera * position4d;

	let tex_coords = vec2<f32>(model.position[0] + 0.5, 1.0 - (model.position[1] + 0.5));

	out.clip_position = position;
	out.texture_coordinates = tex_coords * instance.texture_size + instance.texture_coordinates;
	return out;
}

@group(1) @binding(0)
var t_diffuse: texture_2d<f32>;
@group(1) @binding(1)
var s_diffuse: sampler;

@fragment
fn fs_main(in: VertexOutput) -> @location(0) vec4<f32> {
	return textureSample(t_diffuse, s_diffuse, in.texture_coordinates);
}